Submit Hint Search The Forums LinksStatsPollsHeadlinesRSS
14,000 hints and counting!


Click here to return to the ''Bookmark' regular MP3s in iTunes for later listening' hint
The following comments are owned by whoever posted them. This site is not responsible for what they say.
'Bookmark' regular MP3s in iTunes for later listening
Authored by: notverypc on Apr 12, '05 03:30:36PM
Here's the script I use. It converts to ACC with Bookmarkablity and deletes the orginal file: Needs to be saved as an Application and you use it as a droplet.

on run
	display dialog "To use this script, please drag files or folders onto its Finder icon."
end run

on open myFinderList
	repeat with myFinderItem in myFinderList
		my Process_Item(myFinderItem as item)
	end repeat
	display dialog "All Done!!" buttons {"OK"} default button 1 with icon stop giving up after 10
end open

on Process_Item(ThisItem)
	if folder of (info for ThisItem) then
		my Process_Folder(ThisItem)
	else
		my Process_File(ThisItem)
	end if
end Process_Item

on Process_Folder(thisFolder)
	tell application "Finder" to set FolderContents to every item of thisFolder
	repeat with ThisItem in FolderContents
		my Process_Item(ThisItem as alias)
	end repeat
end Process_Folder

on Process_File(thisFile)
	
	set target_playlist to "Radio Shows"
	set deleteOriginals to true
	set makeBookmarkable to true
	set encoderName to "AAC Encoder"
	
	if class of thisFile is not list then
		set thisFile to {thisFile}
	end if
	
	set newFileList to {}
	
	with timeout of 864000 seconds
		tell application "iTunes"
			set lastEncoder to current encoder --Preserve the users last setting
			set current encoder to encoder named encoderName
			
			copy (convert thisFile) to trackList
			if class of trackList is not list then
				set trackList to {trackList}
			end if
			
			repeat with newTrack in trackList
				
				--set name of newTrack to ""
				--set artist of newTrack to ""
				--set album of newTrack  to ""
				set genre of newTrack to "Podcast"
				set the volume adjustment of the newTrack to 100
				--set year of newTrack to ""
				--set comment of newTrack to ""
				
				set newFileList to newFileList & (location of newTrack as alias)
			end repeat
			
			set current encoder to lastEncoder --Restory the users last setting
			
		end tell
	end timeout
	
	if makeBookmarkable is true then
		tell application "Finder"
			repeat with aFile in newFileList
				update aFile
				set file type of aFile to "M4B "
			end repeat
		end tell
	end if
	
	if deleteOriginals is true then
		do shell script ("rm " & (quoted form of POSIX path of thisFile)) -- Deletes Original File
	end if
	
	
end Process_File
NOTE: I have

[ Reply to This | # ]
'Bookmark' regular MP3s in iTunes for later listening
Authored by: bakalite on Apr 12, '05 04:35:59PM

Won't this degrade the quality by re-encoding the file?



[ Reply to This | # ]
'Bookmark' regular MP3s in iTunes for later listening
Authored by: DougAdams on Apr 13, '05 06:41:11AM

Yes.

---
Doug's AppleScripts for iTunes
http://www.dougscripts.com/itunes/



[ Reply to This | # ]