Submit Hint Search The Forums LinksStatsPollsHeadlinesRSS
14,000 hints and counting!

Create Outlook-like reminders for Mail System 10.8
I wanted Mail to remind me to follow up on a given e-mail, as Outlook does. I realized that Reminders and Mail can do just that.

If you want to set a reminder to follow up on an e-mail, just open Reminders, and without even switching back to Mail, drag the e-mail you want to be reminded about to Reminders. It will create a new task with a link to your specific e-mail. You may add an alert, and you will never forget to follow up on an email again.

[kirkmc adds: This isn't very different from this hint, but it puts it in a different context. I hadn't used Outlook in ages, but its Follow Up menu item (in a contextual menu when you right-click on an e-mail) is very practical.

I'm still amazed that there is no direct link between Mail, Reminders and Calendar. This hint seems a good way to connect them, though it requires several steps. In Outlook, you have a number of default follow up times, whereas here you need to set the date and/or time of the reminder manually. Note to automator experts: I tried to create a workflow that would do this, but it wouldn't let me set a time. Feel free to try and build something useful.]
    •    
  • Currently 4.00 / 5
  You rated: 5 / 5 (5 votes cast)
 
[8,390 views]  

Create Outlook-like reminders for Mail | 6 comments | Create New Account
Click here to return to the 'Create Outlook-like reminders for Mail ' hint
The following comments are owned by whoever posted them. This site is not responsible for what they say.
Create Outlook-like reminders for Mail
Authored by: prachigauriar on Sep 11, '12 09:59:11AM

I am by no means an Automator or Applescript expert, but the Applescript below can be used with Automator to create reminders for each selected Mail message. Create an Automator workflow whose first item is Get Selected Mail Messages and whose second is Run Applescript with the script below.

The reminders are set to go into the “Follow-Ups” list with a reminder date of 9am the next day. If you want different values, it should be fairly obvious what to change in the script.

on run {input, parameters}
	set the_reminders to {}
	
	repeat with the_message in input
		tell application "Mail"
			-- If the subject starts with any number of "Re:" or "Fwd:", remove them
			set the_subject to do shell script "echo '" & the_message's subject & "' | sed -E -e 's/^((Re|Fwd): )*//g'
			set the_name to "Re: " & the_subject
			set the_body to "message://%3c" & the_message's message id & "%3e"
		end tell
		
		tell application "Reminders"
			tell list "Follow-Ups"
				-- Set the date to 9am tomorrow
				set reminder_date to (current date) + 1 * days
				set time of reminder_date to 60 * 60 * 9
				
				set the_reminder to (make new reminder with properties {name:the_name, body:the_body, remind me date:reminder_date})
				set end of the_reminders to the_reminder
			end tell
		end tell
	end repeat
	return the_reminders
end run

The script returns a list of the reminders that were created, which could then be passed to your next Automator action.

Edited on Sep 11, '12 10:22:42AM by prachigauriar


[ Reply to This | # ]
Create Outlook-like reminders for Mail
Authored by: drm0223 on Sep 15, '12 01:11:22PM

The work flow doesn't work, as it appears.

A '"' is needed a the end of the line starting
set the_subject to do shell script ...

The statements
tell list "Follow-ups"
end tell
are not needed and generate errors.

With these two changes, I got it to work! Thanks for the idea!



[ Reply to This | # ]
Create Outlook-like reminders for Mail
Authored by: prachigauriar on Sep 17, '12 07:56:57AM
Right, I forgot a close " on the sed command. If you update it as follows, things will work.

on run {input, parameters}
	set the_reminders to {}
	
	repeat with the_message in input
		tell application "Mail"
			-- If the subject starts with any number of "Re:" or "Fwd:", remove them
			set the_subject to do shell script "echo '" & the_message's subject & "' | sed -E -e 's/^((Re|Fwd): )*//g'"
			set the_name to "Re: " & the_subject
			set the_body to "message://%3c" & the_message's message id & "%3e"
		end tell
		
		tell application "Reminders"
			tell list "Follow-Ups"
				-- Set the date to 9am tomorrow
				set reminder_date to (current date) + 1 * days
				set time of reminder_date to 60 * 60 * 9
				
				set the_reminder to (make new reminder with properties {name:the_name, body:the_body, remind me date:reminder_date})
				set end of the_reminders to the_reminder
			end tell
		end tell
	end repeat
	return the_reminders
end run
As for the tell list "Follow-Ups" thing, that adds it to a specific list named "Follow-Ups". If you remove the tell block, it’ll probably just add it to the default (or currently selected) list of reminders.
Edited on Sep 17, '12 08:00:15AM by prachigauriar


[ Reply to This | # ]
Create Outlook-like reminders for Mail
Authored by: garythemacguy on Sep 11, '12 10:38:39AM

> just open Reminders

If you're prepared to give Reminders a position in your Dock, you don't even need to open it first. Just drag the message over the Reminders icon in the Dock and it will

(1) open automatically and
(2) create the new reminder for you.

I think I might just leave Reminders in the Dock... :-)



[ Reply to This | # ]
Create Outlook-like reminders for Mail
Authored by: janpeeters on Sep 12, '12 01:40:54PM
Another option is to buy the brilliant MailTags by Indev. http://www.indev.ca/MailTags.html It's a paid solution but I like it a lot and it has many added features. I'm afilliated with nor paid by Indev by the way, just love their products.

[ Reply to This | # ]
Create Outlook-like reminders for Mail
Authored by: jfw on Sep 17, '12 07:30:48AM

This hint is helpful if you really want your email reminders to be time based. I know that was the reason for the hint but I rarely have the need to be reminded to follow up at a specific time.

In general, I find it faster & easier to use flags. I customized a "Follow Up" flag and assign that with a single click to any email (received or outgoing). Then I have a smart mailbox to show me all of them, which I can monitor at regular intervals (like daily) rather than being interrupted with a reminder when I'm doing something else.

I also like having all my messages I need to follow up to marked right in front of me in Mail.



[ Reply to This | # ]