Submit Hint Search The Forums LinksStatsPollsHeadlinesRSS
14,000 hints and counting!

Convert iTunes podcast tracks to regular music files Apps
Although there are a few hints that relate to this, I think I've streamlined the process for taking a podcast episode (such as from the excellent KEXP Song of the Day podcast) and automatically stripping the podcast ID3 tag, deleting the podcast episode, and re-adding the track to your iTunes Music Library as a regular MP3 file.

First, you must download fixid3tag. Then in Terminal, type gcc fixid3tag.c -o fixid3tag (you must have the Developer Tools installed). Put the fixid3tag binary someplace; I put mine in ~/Documents.

Next, take the belwo AppleScript and put it in ~/Library » iTunes » Scripts. The first couple of lines are used to specify two important file locations -- the location of the fixid3tag binary, and the location of your temporary folder (I used ~/Desktop/Fixed.)
tell application "Finder"
  --This is where you put the path to the compiled fixid3tag
  set FixerLocation to "~/Documents/fixid3tag"
  --This is the path to your temporary folder
  set FixedFolder to (folder "Fixed" in desktop) as alias
end tell

tell application "iTunes"
  set trackList to the selection of window 1 
  repeat with theTrack in trackList
    set theTrackName to ((the location of theTrack))
    do shell script FixerLocation & " " & quoted form of POSIX path of theTrackName
    do shell script "cp " & quoted form of POSIX path of theTrackName & " " & quoted form of POSIX path of FixedFolder
    delete theTrack
    do shell script "rm " & quoted form of POSIX path of theTrackName
  end repeat
end tell

--add fixed files to iTunes
tell application "Finder"
  set theseFiles to (files of folder FixedFolder as alias list)
end tell
try
  tell application "iTunes" to add theseFiles
on error err
end try

--delete converted temp files
tell application "Finder"
  delete every item of folder FixedFolder
end tell
Now, just select one or several podcast episodes, and they will disappear from the Podcast listing, and reappear in your iTunes library.

[robg adds: I haven't tested this one.]
    •    
  • Currently 1.00 / 5
  • 1
  • 2
  • 3
  • 4
  • 5
  (3 votes cast)
 
[19,793 views]  

Convert iTunes podcast tracks to regular music files | 18 comments | Create New Account
Click here to return to the 'Convert iTunes podcast tracks to regular music files' hint
The following comments are owned by whoever posted them. This site is not responsible for what they say.
Convert iTunes podcast tracks to regular music files
Authored by: hamarkus on May 21, '08 08:19:54AM

How do I place the folder 'fixed' somewhere else then the Desktop? I tried modifying this line as follows, but it does not work?
set FixedFolder to (folder "Fixed" in "/Users/myusername/Music") as alias



[ Reply to This | # ]
Convert iTunes podcast tracks to regular music files
Authored by: xfloydianslipx on May 21, '08 09:13:10AM
set FixedFolder to "harddrivename:Users:username:Music:Fixed" as alias

[ Reply to This | # ]
Convert iTunes podcast tracks to regular music files
Authored by: xfloydianslipx on May 21, '08 09:12:04AM

Great hint - works perfectly and quickly!

@hamarkus: Applescript handles paths differently than standard POSIX paths.

Try: set FixedFolder to "harddrivename:Users:username:Music:Fixed" as alias



[ Reply to This | # ]
Thanks (also to xfloydianslipx)
Authored by: hamarkus on May 21, '08 12:06:09PM

Confusingly enough, the first path to the binary 'fixid3tag' uses the Unix conventions, presumably because it just creates a string that is then used to assemble the shell command.



[ Reply to This | # ]
Convert iTunes podcast tracks to regular music files
Authored by: treck on May 21, '08 10:37:12AM

You can just Select the song in iTunes, then go to Advanced->Convert ID3 Tags, then select version 1.1 and the song will appear in your library as a regular song.

---
treck



[ Reply to This | # ]
Guess what... this menu option is greyed out on my podcasts
Authored by: hamarkus on May 21, '08 12:27:58PM

Could be because they are AAC or because they contain chapters.



[ Reply to This | # ]
Convert iTunes podcast tracks to regular music files
Authored by: asmeurer on May 21, '08 12:05:43PM

Is there a good reason for doing this? It seems that the only difference is that you don't have the CLEAN box next to songs in playlists. On the other hand, you would lose any information in the description box.



[ Reply to This | # ]
Convert iTunes podcast tracks to regular music files
Authored by: asmeurer on May 21, '08 12:58:25PM

Ah. I just noticed that podcasts are listed separately in the browser. That is annoying. I guess iTunes could also potentially delete all your podcasts if you change the preferences.

Is there any way to preserve the description data though, maybe by putting it in the lyrics?

Another question, why do tracks need to be re-added as this script does?



[ Reply to This | # ]
Does this work with chapters?
Authored by: hamarkus on May 21, '08 12:14:12PM

After sorting out the paths, all it does now for me is to re-add the podcast, now again checked (I unchecked it before) and with the un-played status.
I tried it on a podcast with chapters, btw.
It would be cool if it only added the currently selected chapter (with its album art and description as the new title). Currently this probably could only work by setting the start and stop time. AFAIK, only Rogue Amoeba Fission can split AAC files, for MP3 files open source software exists however.



[ Reply to This | # ]
Convert iTunes podcast tracks to regular music files
Authored by: tonyboy on May 22, '08 02:12:31PM

What I like to do is keep the same ringtones for everyone, but associate their contact information with a picture of them, phone in hand.

This way, whenever my friends call me, I get nice big pictures of them calling me. :)

- Anthony



[ Reply to This | # ]
Convert iTunes podcast tracks to regular music files
Authored by: wildness on May 22, '08 09:28:23PM

OR, you can select the track in the podcasts and choose "Convert Selection to MP3" and magically iTunes will create a new version of in its own folder that is in your library and ready to use.



[ Reply to This | # ]
Convert iTunes podcast tracks to regular music files
Authored by: goatee on Sep 22, '08 07:38:16PM

With iTunes 8.0 hightlight the podcast then go to Advanced select "Create AAC Version" ..... it is then added to your library ..... simple



[ Reply to This | # ]
Convert iTunes podcast tracks to regular music files
Authored by: rebmamber on Oct 06, '09 10:24:39AM

There is a much simpler way than has been discussed here.

1. Select files in podcast.
2. Go to "Get Info"
3. In Options Tab, change Media Kind to Music
(If you want it to no longer skip when shuffling, change that also, same goes for remember playback info)

The podcasts are now in your library, no need to create new an delete old files. This works for the most recent update of itunes (9), not sure about earlier versions.



[ Reply to This | # ]
Convert iTunes podcast tracks to regular music files
Authored by: excarnate on Nov 14, '09 10:34:22PM

Your tip doesn't work. There is a popup menu for it, but it is grayed out. iTunes 8.2.1. I'm implementing the OP's tip, it seems to be the cleanest and best way.



[ Reply to This | # ]
Convert iTunes podcast tracks to regular music files
Authored by: everkleer80 on Nov 16, '09 08:16:20AM

I don't think you can change Media Kind to/from Podcast prior to iTunes 9.



[ Reply to This | # ]
It works, but...
Authored by: excarnate on Nov 15, '09 11:20:11AM

It works, but it would be nice to parse some of the common fields from KEXP and KCRW to fill in the Artist, Song, and Album correctly. Ah well, it is nice not to have to worry that listening to a song will cause it to disappear (the Autodelete setting keeps getting turned back on).



[ Reply to This | # ]
It works, but...
Authored by: excarnate on Dec 04, '09 11:50:47AM
I think I found something (Track Parser) that will move things around for me.

I notice this line in the script:
delete every item of folder FixedFolder
That's not very good! I want to use ~/Library/Caches/TemporaryItems/ but it deletes everything there. I tried changing it to:
delete theseFiles
but that also deletes everything...I see why, now. Fixing this is beyond my time available + skill available.

Essentially the script assumes that it has a folder dedicated to its own use, when it should keep track of, well, tracks, or better yet, make and destroy its own temp folder within the temp folder. I think.
Edited on Dec 04, '09 11:54:49AM by excarnate


[ Reply to This | # ]
Important Fix!
Authored by: excarnate on Dec 07, '09 11:29:02PM

The script as originally written will delete everything in whatever folder is chosen. Which could be bad. Here is a briefly tested fix that uses a folder in the user's Temporary Items folder. I only added the if/else/end.


tell application "Finder"
	--This is where you put the path to the compiled fixid3tag
	set FixerLocation to "/usr/local/bin/fixid3tag"
	--This is the path to your temporary folder
	-- Quick hack to stop stepping on all items in whatever folder was chosen, sheesh, what if someone picked ~/Documents?
	if not (exists folder "podcast2music" of folder (path to temporary items from user domain)) then
		set FixedFolder to (make new folder at (path to temporary items from user domain) with properties {name:"podcast2music"}) as string
	else
		set FixedFolder to folder "podcast2music" of folder (path to temporary items from user domain) as string
	end if
end tell

tell application "iTunes"
	set trackList to the selection of window 1
	repeat with theTrack in trackList
		set theTrackName to ((the location of theTrack))
		do shell script FixerLocation & " " & quoted form of POSIX path of theTrackName
		do shell script "cp " & quoted form of POSIX path of theTrackName & " " & quoted form of POSIX path of FixedFolder
		delete theTrack
		do shell script "rm " & quoted form of POSIX path of theTrackName
	end repeat
end tell

--add fixed files to iTunes
tell application "Finder"
	set theseFiles to (files of folder FixedFolder as alias list)
end tell
try
	tell application "iTunes" to add theseFiles
on error err
end try

--delete converted temp files
tell application "Finder"
	delete every item of folder FixedFolder
end tell
Edited on Dec 07, '09 11:54:12PM by excarnate


[ Reply to This | # ]