Submit Hint Search The Forums LinksStatsPollsHeadlinesRSS
14,000 hints and counting!

Send multiple SMS and MMS via Mail or iPhone Mail Apps
Using Teleflip (a free service with sign-up; Wikipedia entry), you can send SMS and MMS messages via any email client. This blog post contains AppleScript code that will parse mobile numbers in your Address Book, and add them as email addresses in a 1234567890@teleflip.com format. Here's the source (robg: with permission of the author) in case the blog post ever vanishes:
tell application "Address Book"
	repeat with this_person in every person
			set the_number to ""
			repeat with i from 1 to the count of phone in this_person
				if label of phone [i] of this_person as string is "Mobile" then
					set the_number to value of phone [i] of this_person as string
				end if
			end repeat
			if the_number is not "" then
				set isAlreadySet to "0"
				repeat with i from 1 to the count of email in this_person
					if (value of email [i] of this_person as string) ends with "@teleflip.com" then
						set isAlreadySet to "1"
					end if
				end repeat
				if isAlreadySet is "0" then
					make new email at end of emails of this_person with properties {label:"other", value:my stripSymbolsAddEmail(the_number)}
				end if
			end if
		end repeat
	end tell

	on stripSymbolsAddEmail(inputText)
		set theSymbols to "().- "

		set prevTids to AppleScript's text item delimiters
		repeat with i in theSymbols
			set AppleScript's text item delimiters to i
			set inputText to inputText's text items
			set AppleScript's text item delimiters to prevTids
			set inputText to inputText as text
		end repeat
		if character 1 of inputText is not "1" then
			set inputText to ("1" & inputText)
		end if
		set inputText to (inputText & "@teleflip.com")
		inputText
	end stripSymbolsAddEmail
	-- thanks to http://applescriptsourcebook.com/viewtopic.php?pid=47366 for this part!
Using the script, you can send SMS and MMS messages to multiple contacts from your Mac or iPhone's Mail with ease. If you don't wish to use Teleflip, and you know the carriers for your contacts, then you can use these email address suffixes:
  • Alltel: 1234567890@message.alltel.com
  • AT&T: 1234567890@mms.att.net
  • Boost Mobile: 1234567890@myboostmobile.com
  • Cingular (AT&T): 1234567890@mms.mycingular.com
  • Einstein PCS: 1234567890@einsteinmms.com
  • Sprint: 1234567890@messaging.sprintpcs.com
  • T-Mobile: 1234567890@tmomail.net
  • US Cellular: 1234567890@mms.uscc.net
  • Verizon Wireless: 1234567890@vzwpix.com
  • Virgin Mobile: 1234567890@vmobl.com
[robg adds: I haven't tested this one.]
    •    
  • Currently 2.33 / 5
  You rated: 4 / 5 (9 votes cast)
 
[38,559 views]  

Send multiple SMS and MMS via Mail or iPhone Mail | 10 comments | Create New Account
Click here to return to the 'Send multiple SMS and MMS via Mail or iPhone Mail' hint
The following comments are owned by whoever posted them. This site is not responsible for what they say.
Send multiple SMS and MMS via Mail or iPhone Mail
Authored by: @man on Dec 12, '07 07:50:50AM

the verizon address supplied is for pix messages only.

to send a text message, use 1234567890@vtext.com



[ Reply to This | # ]
Send multiple SMS and MMS via Mail or iPhone Mail
Authored by: mikedfunk on Dec 12, '07 08:59:41AM

I got an applescript error when trying to run that script in leopard.



[ Reply to This | # ]
Send multiple SMS and MMS via Mail or iPhone Mail
Authored by: whenders0n on Dec 12, '07 12:18:16PM

Did you paste the code from the blog? There was an issue with wordpress automatically converting quotes to fancy quotes but now it is fixed.



[ Reply to This | # ]
Send multiple SMS and MMS via Mail or iPhone Mail
Authored by: M-3 on Dec 12, '07 09:50:03AM

We've been doing this at work on our Nextel phones for a long time now. For Nextel use:

1234567890@messaging.nextel.com



[ Reply to This | # ]
Send multiple SMS and MMS via Mail or iPhone Mail
Authored by: Lutin on Dec 12, '07 02:12:25PM

I would love to have the same kind of service in France. Does any one knows one?



[ Reply to This | # ]
Send multiple SMS and MMS via Mail or iPhone Mail
Authored by: cawaker on Dec 12, '07 03:26:38PM

I do this just by directly emailing the phone numbers with the above listed suffixes. all the providers have email to text gateways that convert the email to a text.

So the teleflip part isnt needed in most cases.



[ Reply to This | # ]
Send multiple SMS and MMS via Mail or iPhone Mail
Authored by: limsilas on Dec 12, '07 03:29:41PM

there is a quicksilver telefilp plug-in available, which correctly parses all addressbook entries.

...but be careful, as teleflip adds a whopping 39 or so characters to your text message, plus the number of characters of your e-mail address. so don't write a novel.



[ Reply to This | # ]
Would be better as a Plug-in
Authored by: alexmathew on Dec 12, '07 05:30:24PM

I was looking for something similar to this to take Fax numbers and use Internet Fax services such as Jfax, Efax, Maxemail etc. The address would be some thing like 18885551212@maxemailsend.com where 18885551212 is the fax number of the contact. However, I am not sure if I want to add a site specific info like Maxemail - or Teleflip in this case - to every one of my contacts. If the site/company goes out of business, I'm left with all these e-mail addresses that I would have to change manually or write another script.

Would a better solution be to use an Addressbook plug-in to do this on the fly ? - so that I can click on a fax number ( mobile number in your case) and choose "send Fax/Teleflip via e-mail to". The plug-in could just do the parsing etc on the fly and create an e-mail in Mail?
AM



[ Reply to This | # ]
Would be better as a Plug-in
Authored by: whenders0n on Dec 13, '07 09:52:40AM

That would be cool but the point of this script was more for being able to send free SMS's via an iPhone/Blackberry.



[ Reply to This | # ]
Here it is as a plug-in
Authored by: rickybuchanan on Dec 14, '07 12:07:10AM
I use a service in Australia - messagenet.net.au - which requires the same mobilenumber@their.server format and hacked together a plugin to do exactly what you described. Feel free to use/modify/etc.:


using terms from application "Address Book"
	on action property
		return "phone"
	end action property
	
	on action title for aPerson with aPhone
		return "SMS With MessageNet"
	end action title
	
	on should enable action for aPerson with aPhone
		return true
	end should enable action
	
	on perform action for aPerson with aPhone
		set fullName to (name of aPerson as string)
		
		set telephone to ""
		if value of aPhone is not missing value then set telephone to value of aPhone
		
		-- TODO Remove any non-number characters from the string
		-- Hack for now: Remove spaces
		set AppleScript's text item delimiters to " "
		set telephone to telephone's text items
		set AppleScript's text item delimiters to ""
		set telephone to "" & telephone
		set AppleScript's text item delimiters to {""}
		
		set emailAddress to telephone & "@messagenet.com.au"
		
		-- display dialog "'" & fullName & "' - '" & emailAddress & "'"
		
		tell application "Mail"
			set newMessage to make new outgoing message with properties {subject:fullName & " <" & emailAddress & ">", content:""}
			tell newMessage
				make new to recipient at end of to recipients with properties {address:emailAddress, name:fullName}
				set visible to true
			end tell
			activate
		end tell
	end perform action
end using terms from

Ricky

---
[Please excuse mistakes/brevity, typed via on-screen keyboard due to disability]

[ Reply to This | # ]