Submit Hint Search The Forums LinksStatsPollsHeadlinesRSS
14,000 hints and counting!

Listen to podcasts at 1.5x speed Desktop
I subscribe to far-too-many podcasts now, and I've found that most of the podcasters can actually be cleanly understood even if you speed up their speech by 50%. So, when my iTunes shows that I have 45 minutes left on a podcast, and I'd rather hear that in 30 minutes, I pull down my script menu to reveal and execute the following AppleScript (saved in my user's Library -> Scripts -> Applications -> iTunes folder as Play this song at 1.5x):
tell application "iTunes"
  pause
  set my_track to location of current track
  set my_seconds to player position
end tell

tell application "QuickTime Player"
  open my_track
  set my_movie to first movie
  set ts to time scale of my_movie
  set current time of my_movie to my_seconds * ts
  set rate of my_movie to 1.5 -- starts playing
end tell
Basically, this tells iTunes to stop playing the podcast, figures out where I am in the podcast, then tells QuickTime Player to start playing the podcast at the same place (within a second), but at 1.5 times the speed. Note that the pitch is unaffected -- only the playback rate changes.

I haven't done a lot of testing with what happens when you have multiple windows already open in Quicktime Player, so I could be wrong on guessing my_movie in the script. Feedback welcome!
    •    
  • Currently 3.23 / 5
  You rated: 3 / 5 (13 votes cast)
 
[89,323 views]  

Listen to podcasts at 1.5x speed | 45 comments | Create New Account
Click here to return to the 'Listen to podcasts at 1.5x speed' hint
The following comments are owned by whoever posted them. This site is not responsible for what they say.
Listen to podcasts at 1.5x speed
Authored by: cssbz on Jan 06, '06 07:40:49AM

Great hint, ta! I had to put my script in my user's Library -> iTunes -> Scripts folder before this would work, BTW, perhaps because I have some existing scripts there?



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: merlyn on Jan 06, '06 11:10:25AM

Ahh, right, for iTunes, it can also use a separate folder. I have the applescript menu enabled, so I can access general applescripts at all times and specific applescripts per application. You are correct for iTunes, for people who don't have the Applescript menu enabled.



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: claudio on Jan 06, '06 08:30:54AM

Coooool!
Although I like hearing at a rate of 1.33, this is more comfortable for me.

Cheers,
Claudio

---
- claudio



[ Reply to This | # ]
Works for video Podcasts as well, but...
Authored by: claudio on Jan 06, '06 08:41:56AM

...if you switch to Full-Screen-Mode, the rate switches back to 1.0

---
- claudio



[ Reply to This | # ]
Works for video Podcasts as well, but...
Authored by: merlyn on Jan 06, '06 11:08:31AM

Apparently, setting the playback rate from Applescript doesn't affect the GUI you get on command-K. So, if you want to mess with the GUI, pull up command-K, then set "playback rate" to whatever you want, then hit full screen.



[ Reply to This | # ]
Works for video Podcasts as well, but...
Authored by: htlmac on Jun 13, '06 05:40:29PM

QuickTime's AV control can adjust pitch shift, treble, etc. I found lower those values help.

Can that be scripted?

I have some reason for not upgrading to 10.4. For example, diskutil's restore to firewire drives working for me in 10.3 but not in 10.4.

Thanks for the script(s)!



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: dcipjr on Jan 06, '06 08:44:47AM

I'm pretty sure that converting the podcast to AAC (if it isn't already in AAC), and renaming the extension to .m4b will make it look like an audiobook to the iPod. Therefore, if you're listening to a podcast on a 4G iPod or newer, you should be able to speed up playback like you can with audiobooks.

Can anyone confirm? I don't have a 4G iPod (I have a 3G).

Anyone else also think that speeding up playback should be an option in the next version of iTunes?



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: MtnBiker on Jan 06, '06 11:45:18AM
This didn't work for me. But I am a newbie to the iPod and file manipulation. For the record I converted a mp3 recorded Internet Radio broadcast to AAC, and then changed extension to m4b and didn't show as Audio Book, but still showed up as Music. Nano for Christmas and I'm trying to figure out the smoothest way to get Podcasts to my Nano. The ones I can subscribe to seem to work well. But the Internet Radio I have to record is more work. I'm trying the free solutions first. RadioRecorder seems to function, but with my PowerMac I have to prevent sleep which is less than ideal. Also with my local NPR station I'm getting frequent drop outs which sometimes causes the Nano to stop (and not restart). At a minimum are quite irritating. Maybe it's because I'm using my Mac while recording. More work to do.

---
Hermosa Beach, CA USA

[ Reply to This | # ]

Listen to podcasts at 1.5x speed
Authored by: van2van2 on Jan 08, '06 08:59:13PM

Actually, you need to change the extention to m4b plus use a tool like Super Get Info (http://www.barebones.com/products/super/index.shtml) to change its system extension to m4b. Doing this and adding artwork if the file is already on your iPod will update it and make it an audiobook..



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: shadownight on Jan 06, '06 11:06:21AM

Very cool!! Try listening to a song for fun... you'll hear hysterical singers!



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: neuralstatic on Jan 06, '06 12:01:46PM

pitch is unaffected, for real?



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: TimStalin on Jan 06, '06 05:24:05PM
pitch is unaffected, for real?

Yep, it works exactly as advertised. Handy script, cheers merlyn.

[ Reply to This | # ]
Not for me
Authored by: MrJuicy on Jan 07, '06 01:17:17AM

Testing an mp3 podcast (Harry Shearer's Le Show) on iTunes 4.9 on Mac OS X 10.3.9, with QuickTime Player 6.5.2, results in higher pitched playback, not time compression.



[ Reply to This | # ]
Not for me
Authored by: merlyn on Jan 07, '06 04:19:10AM

Ahh, so tiger is better on this. No surprise. Time to upgrade!



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: easyE on Jan 06, '06 04:43:41PM
I added these lines so the user can input the speed each time the script is run, just change "1.5" to "rate" in the original script.

tell application "Finder"

    set ans to ""
    display dialog "Enter Rate:" default answer ans buttons {"OK"} default button 1
    set ans to text returned of the result
    set rate to ans * 1
end tell



[ Reply to This | # ]

Listen to podcasts at 1.5x speed
Authored by: easyE on Jan 06, '06 04:57:11PM
Correction... Add this between the iTunes and Quicktime paragraphs and change "1.5" to "speed".

tell application "Finder"

    set speed to ""
    display dialog "Enter Rate:" default answer speed buttons {"OK"} default button 1
    set speed to text returned of the result speed * 1
end tell


[ Reply to This | # ]
Listen to podcasts at 1.33x speed and at same volume
Authored by: xavierbdm on Jan 09, '06 07:28:58AM
Here is a version that:
- gets rid of one or two bugs in the above lines
- keeps same volume setting between iTunes and QuickTime player
- allows for manual entry of rate (default is 1.33) (we don't need the Finder for the dialog!)
- brings QuickTime player to front, so you can stop/close if need be.

tell application "iTunes"
	set currentVolume to sound volume
	pause
	set my_track to location of current track
	set my_seconds to player position
end tell

set speed to "1.33"
display dialog "Enter Rate:" default answer speed buttons {"OK"} default button 1
set speed to text returned of the result

tell application "QuickTime Player"
	open my_track
	set my_movie to first movie
	set ts to time scale of my_movie
	set current time of my_movie to my_seconds * ts
	set sound volume of my_movie to currentVolume
	set rate of my_movie to speed -- starts playing
end tell
As usual, paste Script Editor, save in ~/Library/iTunes/Scripts/ (or somewhere else if your script menu is activated, but then this works too)

---
iMac G4 17 800/512/80 + powerbook firewire G3 500/512/30

[ Reply to This | # ]

Listen to podcasts at 1.33x speed and at same volume
Authored by: xhide on Jan 13, '06 09:38:45PM

maintain same volume only works when "Sound Check" is enabled in iTunes preferences playback setting. For those with "Sound Check" disabled need to delete the lines where set sound volume.

Thanks for the tips



[ Reply to This | # ]
Listen to podcasts at 1.33x speed and at same volume
Authored by: htlmac on Jun 13, '06 11:30:47PM
the ranges of sound volume differ between iTune and QTime.
thus,

set sound volume of my_movie to 256 * (currentVolume / 100)

as iTune has min 0 and max 100 while QTime has 256 as 100%.


here is my reversion:

tell application "iTunes"
play -- in case not already playing
pause
set currentVolume to sound volume
set my_track to location of current track
set my_seconds to player position
end tell

set speed to "1.33"
display dialog "Enter Rate (0.50 ~ 3.00):" default answer speed buttons {"OK"} default button 1
set speed to text returned of the result

tell application "QuickTime Player"
set show av controls window to true
set show equalizer to true
set show movie info window to true

open my_track
set my_movie to first movie
set sound volume of my_movie to 256 * (currentVolume / 100)
set rate of my_movie to speed
set treble gain of my_movie to -100
set current time of my_movie to (my_seconds * (time scale of my_movie))
end tell

display dialog "Click OK to return to 1x:" buttons {"OK"} default button 1

tell application "QuickTime Player"
set my_movie to first movie
set my_seconds to ((current time of my_movie) / (time scale of my_movie))
set auto play of my_movie to false
set auto present of my_movie to false
set auto quit when done of my_movie to true
close my_movie
end tell


tell application "iTunes"
set player position to my_seconds
play
end tell


[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: doneitner on Jan 06, '06 05:08:11PM

This is fabulous! I emailed Apple some time ago asking if this could be built into iTunes as a standard feature for just this reason. Now, do you know of a way to make this work with DVD Player 4.6? As far as I can tell, DVD Player only allows integer values for the playback speed.



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: Julio on Jan 06, '06 05:39:39PM

without this AppleScript specifying an incremental increase of 1 for the playcount, listeners will end up with podcast playlists that iTunes thinks contains many unplayed podcasts which in turn will eventually auto unsubscibe in iTunes..



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: u2mr2os2 on Jan 06, '06 06:39:05PM
Here's a companion script to stop the one playing in Quicktime and resume the one in iTunes right where you've gotten to while listening to it in Quicktime.

tell application "iTunes"
	pause
	set my_track to location of current track
end tell

tell application "QuickTime Player"
	set my_movie to first movie
	set ts to time scale of my_movie
	set my_seconds to (current time of my_movie) / ts
	close my_movie
end tell

tell application "iTunes"
	set player position to my_seconds
	play
end tell
Limitations are that you need to keep the track of interest as the current track in iTunes. So far, this doesn't have error checking to make sure of this. If you finish the podcast in Quicktime, it leaves it at the end, so when you run this script, it will set the play time to the end, which makes it jump back to the beginning and increment the play count in iTunes.

[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: u2mr2os2 on Jan 06, '06 06:51:55PM

Actually, that "pause" in the first tell should not be there, but it doesn't matter.



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: merlyn on Jan 06, '06 11:57:44PM
The whole first tell block can be removed. You need to talk to Quicktime Player to stop it and get the current seconds, then talk to iTunes to set the current track to that. Simple!

[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: u2mr2os2 on Jan 07, '06 07:24:48PM

Hey, thanks! I don't know why I didn't see that.



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: captainjc on Jan 06, '06 11:50:22PM

does anyone know of a way to change the pitch of something in itunes?



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: merlyn on Jan 07, '06 03:32:27PM

Not in iTunes, but with the Developer Tools installed, look for the "AU Lab" Application, and you can do it for free. It's a bit tricky, and maybe deserves a hint of its own, so I'll write it up and submit it when I get a chance.



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: easyE on Jan 07, '06 10:46:46AM

Put in a negative number and you can even play the song backwards!



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: rumirocks on Jan 07, '06 10:28:41PM

Thank you, thank you, thank you. Great hint.

Did you know that if you speed up learning tapes, the mind processing the info better and faster. The way to learn complicated info is to hear is as fast as you can.



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: simplyodd on Jan 08, '06 07:02:23PM

Fantastic hints, both the original and the companion to switch back to iTunes. Couldn't get the script to work that prompts for the speed however, which would be nice.

Would it be possible to script Quicktime to use the same volume adjustment that iTunes applied? When Quicktime takes over, on mine, the sound is much lower. A GetInfo on the track in itunes showed the sound set at +6.6db in the Summary tab, which I guess happened b/c I enabled Sound Enhancer or Sound Check pref's in itunes. Displaying Movie Properties in Quicktime does show a volume slider that maxes out at +6db.

Again thanks for sharing these tips,
tom



[ Reply to This | # ]
Speed up Videos too...
Authored by: jammjamm on Jan 09, '06 10:24:27AM

I speed up movies with MPlayer (just hit "]" and "[" to speed up/slow down by 10%) and use Audio Hijack Pro to correct the pitch. This works really well.



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: shadownight on Apr 18, '06 03:11:43PM

This is also really useful for movies, that really don't play well in iTunes for me. If you modify the script to make 1x, you can use it to view your iTunes in QuickTime, just by selecting the script from the menu. Cool!



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: coolbeans on Apr 26, '06 04:05:13PM

I just realized that PC users can have an even better experience listening to podcasts than Mac users. If you use podcasts.yahoo.com to listen to podcasts, they even have a feature on the web UI where you can click to speed podcasts up to 2.0x. Plus, it's good to have all those audio files stored away on someone else's computer so you don't have to burden your own hard drive (of course, you wouldn't be able to listen offline but you can click "download" episode if you want).

Of course, since yahoo podcasts use a windows media plugin for streaming, you can't access them on a Mac unless you click a few times---additionally, the speed feature is not accessible either.

Get a clue, Apple! You seem to be good at leading innovation but amount to dogsh*t when it comes to listening to user feedback.



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: mfc2mfc2 on May 13, '06 02:22:42PM

I was using the above AppleScript on my Mac. I am moving my iTunes library to Windows XP, so I created the below script to do the same thing for iTunes on Windows.

Copy and paste the code into NotePad, save as "1.4SpeedPodcast.js," and double-click the file to execute it. You need to have Windows Script support installed. This is downloaded from Microsoft.com if you don't already have it.


//Editor: Mike Chabot
//Date: May 12, 2006
//Purpose: Play the currently playing podcast or the highlighted podcast at 1.4 speed in QuickTime

var iTunes = WScript.CreateObject("iTunes.Application");
var qt = WScript.CreateObject("QuickTimePlayerLib.QuickTimePlayerApp.1");

if(iTunes.PlayerState != 0) {//0=stopped, 1=playing, 2=ff, 3=rw
	var track=iTunes.CurrentTrack;
	iTunes.Stop();
} else {
	//selected tracks are the ones highlighted, the current track is the one playing or the one loaded
	if(iTunes.SelectedTracks) {
		var track=iTunes.SelectedTracks.Item(1);
		track.Play(); //update the played status
		iTunes.Stop();
	} else if(iTunes.CurrentTrack) {
		var track=iTunes.CurrentTrack;
	} else {
		WScript.Echo('error');
		WScript.Quit(1);
	}
}

iTunes.BrowserWindow.Minimized=1; //minimize iTunes window
qt.Players.Item(1).OpenURL(track.Location);
qt.Players.Item(1).QTControl.Movie.TimeScale=1; //set QT to use seconds for Time attribute.
qt.Players.Item(1).QTControl.Movie.Time=track.BookmarkTime;
qt.Players.Item(1).QTControl.Movie.AudioVolume=iTunes.SoundVolume / 100; //divide by 100 for QT compatibility
qt.Players.Item(1).QTControl.Movie.Play(1.4); //Play at 1.4x speed


[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: scienceandpoetry on Jan 09, '08 09:41:21PM

I added the try statement to allow for the selected track to play if nothing is currently playing. I use iTunes' sound check, which inevitably lowers the volume of all of my tracks, so I also set QT Player's volume lower. I also like the player brought to the front.

tell application "iTunes"
try
pause
set my_track to location of current track
set my_seconds to player position
on error
set my_track to location of item 1 of selection
set my_seconds to 0
end try
end tell

tell application "QuickTime Player"
open my_track
set my_movie to first document
set sound volume of my_movie to 128 --set volume to 50%
set ts to time scale of my_movie
set current time of my_movie to my_seconds * ts
set rate of my_movie to 1.5 -- starts playing
activate
end tell



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: Cezary Okupski on May 15, '09 03:28:49AM
To play audio faster (or convert it that way) using the command line you could use sox (http://sox.sourceforge.net/). In theory you could install it from MacPorts (sudo port install sox), but in practice in order to support MP3 format you have to compile it from source code with MAD and LAME libraries. MacPorts version supports many other formats for example AIF, so you can give it a go. Should there be any interest, I could make a tutorial on this.

[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: Cezary Okupski on May 15, '09 03:49:08PM
Oh, and there is yet another way to accomplish this with mplayer: http://mark.santaniello.com/archives/260

[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: dgold105 on Aug 28, '09 04:10:21PM

This has stopped working for me with Snow Leopard. Anyone know how to fix it to work?



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: PuppyBlade on Sep 14, '09 07:57:15AM
This seemed to fix it for me.

tell application "iTunes"
	pause
	set my_track to location of current track
	set my_seconds to player position
end tell

tell application "QuickTime Player"
	open my_track
	set my_movie to first document
	set ts to rate of my_movie
	set current time of my_movie to my_seconds * ts
	set rate of my_movie to 2.0 -- starts playing
end tell



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: PuppyBlade on Sep 14, '09 08:45:10AM
On second thought, I took out the time scale part, instead of replacing it with rate (that wasn't quite right). This seems to work:

tell application "iTunes"
	pause
	set my_track to location of current track
	set my_seconds to player position
end tell

tell application "QuickTime Player"
	open my_track
	set my_movie to first document
	set current time of my_movie to my_seconds
	set rate of my_movie to 1.5 -- starts playing
end tell


[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: PeeWee on Dec 14, '09 05:39:32AM

Thanks a lot for these scripts.

I would like to use a player like Movist who allows to keep the video window in front of all other windows. So I tried to adapt the script, but it seems that Movist doesn't understand it. Or my appplescript knowledge is too limited anyway.

Can anyone modify the script so that Movist or another player who offers a floating window understands it?



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: VJ Prana on Dec 18, '09 04:43:50PM

I updated this for OS X 10.6 (Snow Leopard)
and also wrote a companion script to send it back to iTunes when your done.

You can download my scripts here:

http://www.reelgeminc.com



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: Tylast on Dec 24, '11 10:08:07PM

Any update to get this to work with the latest iTunes & QT?



[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: KTell on Jan 20, '12 12:55:32PM
Here is my version for OS X Lion, thanks for the previous comments!

tell application "iTunes"
	pause
	
	set myTrack to location of current track
	
	# the player’s position within the currently playing track in seconds
	set mySeconds to player position
end tell

# show a Dialog
set SpeedFactor to 1.5
display dialog "Enter speed factor:" default answer SpeedFactor
set SpeedFactor to text returned of the result


tell application "QuickTime Player"
	activate
	
	# pause all previously opened documents
	set open_docs to documents
	repeat with doc in open_docs
		pause doc
	end repeat
	
	# open the track just played in iTunes
	open myTrack
	
	# get the 'QuickTime' document, MyTrack should be equivalent but it isn't
	set MyMovie to first document
	
	# rewind by 10 seconds
	if mySeconds > 10 then
		set mySeconds to mySeconds - 10
	end if
	
	# set current time
	set current time of MyMovie to mySeconds
	
	# set Speed Factor and start playing
	set rate of MyMovie to SpeedFactor
end tell


[ Reply to This | # ]
Listen to podcasts at 1.5x speed
Authored by: JakeProps on Apr 23, '12 09:57:20PM

Thank you for this. And it's Lion update. Is there a companion Lion script? Thanks again!



[ Reply to This | # ]