Submit Hint Search The Forums LinksStatsPollsHeadlinesRSS
14,000 hints and counting!

View movie trailers and music videos in QT Player Internet
If you want to watch trailers from Apple's trailer page in QuickTime Player instead of in a browser window or through the iTunes Music Store, it can be done pretty easily.

When loading a movie in your favorite browser, view the HTML source for the page and search for .mov. Copy the movie's URL and paste it into the dialog that appears when you select File -> Open URL in New Player (Command-U) in QuickTime Player.

This way, you can view the movie fullscreen if you have QuickTime Pro, and even save the movie to your local drive.

[robg adds: A previous hint provided a script for saving iTunes Music Store videos...]
    •    
  • Currently 1.00 / 5
  • 1
  • 2
  • 3
  • 4
  • 5
  (1 vote cast)
 
[9,637 views]  

View movie trailers and music videos in QT Player | 7 comments | Create New Account
Click here to return to the 'View movie trailers and music videos in QT Player' hint
The following comments are owned by whoever posted them. This site is not responsible for what they say.
View movie trailers and music videos in QT Player
Authored by: wgscott on Jun 30, '04 12:01:23PM
You can save the movie with a control-click or right-click on the embedded movie. Choose "Save as quicktime movie" Try it:

[ Reply to This | # ]
View movie trailers and music videos in QT Player
Authored by: rhowell on Jun 30, '04 12:37:36PM

...only if you have Quicktime Pro.



[ Reply to This | # ]
View movie trailers and music videos in QT Player
Authored by: macsolve on Jun 30, '04 05:16:12PM
I've always missed to be able to control click an embedded movie and choose "Play movie with QuickTime Player", like the Real Player plugin lets me do.
Here's an AppleScript to pass an embedded movie automagically to QT Player. If there are more than one embedded movie on a page it asks which one to view.
I've put this on an iKey hotkey. Very neat.

Note: This script does not see embedded movies inside of frames. Open frame in new tab first.

(* script to pass embedded movie URLs from Safari to QT Player 
   Written by Johan Sölve 2004-04-02 *)
tell application "Safari"
  set BaseUrl to URL of document 1
  if (source of document 1) as string is "" then
    set objecturl to BaseUrl
  else
    set embeds to (do JavaScript "n= '';for (var i=0; i<document.getElementsByTagName('embed').length;i++) 
      {n = n + (document.getElementsByTagName('embed').item(i).src) + \"\\r\"; if(document.getElementsByTagName('embed').item(i).href) 
      {n=n+(document.getElementsByTagName('embed').item(i).href) + \"\\r\"}}" in document 1)
    if (count paragraphs of embeds) > 1 then
      set embeds to items 1 thru -2 of (paragraphs of embeds)
    else
      set embeds to {}
    end if
    
    set objecturl to ""
    if (count embeds) is 1 then
      set objecturl to item 1 of embeds
    else if (count embeds) > 0 then
      set embedsShow to {}
      repeat with thisEmbed in embeds
        tell me to set embedsShow to embedsShow & first item of split(last item of (split(thisEmbed, "/")), "?")
      end repeat
      set choice to (choose from list embedsShow with prompt "Play in QuickTime Player:" default items {last item of embedsShow})
      if choice is not false then
        set counter to 1
        repeat with thisEmbed in embedsShow
          if (thisEmbed as string) is (item 1 of choice) then
            set objecturl to (item counter of embeds)
            exit repeat
          end if
          set counter to counter + 1
        end repeat
      end if
    end if
  end if
end tell

if objecturl is not "" then
  if objecturl does not contain "://" then
    if objecturl begins with "/" then
      set BaseUrl to join(items 1 thru 3 of split(BaseUrl, "/"), "/")
    else
      set BaseUrl to join(items 1 thru -2 of split(BaseUrl, "/"), "/") & "/"
    end if
    set objecturl to BaseUrl & objecturl
  end if
  ignoring application responses
    tell application "QuickTime Player"
      activate
      getURL objecturl
    end tell
  end ignoring
  
end if


on split(theString, splitAt)
  set olddelim to AppleScript's text item delimiters
  set AppleScript's text item delimiters to splitAt
  set theString to every text item of theString
  set AppleScript's text item delimiters to olddelim
  return theString
end split

on join(theString, joinWith)
  set olddelim to AppleScript's text item delimiters
  set AppleScript's text item delimiters to joinWith
  set theString to (theString as string)
  set AppleScript's text item delimiters to olddelim
  return theString
end join


[ Reply to This | # ]
A fine script!
Authored by: Alidoro on Jun 30, '04 09:20:24PM

macsolve, thanks for the script, it works like a charm!



[ Reply to This | # ]
View movie trailers and music videos in QT Player
Authored by: Dale Sorel on Jul 01, '04 04:40:55PM

If you hold down the option key when you hover over the movie link it will automatically download the movie to wherever you've chosen to download files to.



[ Reply to This | # ]
View movie trailers and music videos in QT Player
Authored by: Mac Maven on Oct 09, '04 06:02:54AM

Instead of using the method found on this page, which may not work reliably, go to the temporary folder where downloaded QT movies (Safari, iTunes, etc.) are stored. Choose Go to Folder in the Finder's Go menu and go to: /private/tmp/505/TemporaryItems/



[ Reply to This | # ]
View movie trailers and music videos in QT Player
Authored by: Mac Maven on Oct 09, '04 06:04:08AM

Instead of using the method found on this page, which may not work reliably, go to the temporary folder where downloaded QT movies (Safari, iTunes, etc.) are stored. Choose Go to Folder in the Finder's Go menu and go to: /private/tmp/505/TemporaryItems/

(Sorry for double posting, I'm new here. . .)



[ Reply to This | # ]